mirror of
https://github.com/jorgebucaran/fisher
synced 2024-10-09 09:36:53 +02:00
54212e1cbc
* Improved README, added links to screencasts, updated documentation with new changes and fixed other typos and composition errors. * Removed `fisher update --cache` in favor of `fisher --cache | fisher update` and `fisher uninstall --all` in favor of `fisher --cache | fisher uninstall`. * Fisherman does not move initialization / configuration files following the convention `name`.config.fish to `$fisher_config/functions`, but to `$fisher_config/conf.d` now and evaluates each `*.config.fish` inside at shell start as usual. Closes #13. * Added `fisher --cache[=base]` option to retrieve contents in `$fisher_cache`, eliminating flaky usage of `find(1)`. Closes #11. * Fisherman now generates information about plugins installed via custom URLs. For the description, a shortened version of the URL is used. For the URL the full URL is used. For tags, the URL is fuzzily checked and tags such as _theme_, _plugin_, _config_ and _omf_ are added. The tag _orphan_ is added by default as well. Finally, the author is generated by retrieving the e-mail or username of the author of the first commit in the plugin's repository. Closes #9 and #14. * Changed `--path-in-cache` to `--translate.` This function translates an name or supported URL/URL variation into a path inside `$fisher_cache`. This allows you to treat plugins installed via custom URLs almost like regular plugins if they are installed. Closes #8. * Fixed a bug with `mktemp` failing on some systems. Closes #7. Thanks @tobywf. * Added [CODE_OF_CONDUCT][code_of_conduct]. Closes #6. * Fisherman can now unload themes within the same shell, without having to restart the session. Closes #5. * Fisherman can now load themes within the same shell, without having to restart the session using `exec fish`. Shoddy themes, for example those failing to declare global variables with the `-g` flag still require the session to be reset. See [**related**][bobthefish-19]. Closes #4. * Move `getopts` implementation to `share/getopts.awk`. Closes #3. * Support dots inside URIs in `fisher --validate`. Closes #2.
118 lines
3.2 KiB
Fish
118 lines
3.2 KiB
Fish
function fisher_update -d "Fisherman Update Manager"
|
|
set -l option
|
|
set -l path
|
|
set -l items
|
|
set -l error /dev/stderr
|
|
|
|
getopts $argv | while read -l 1 2
|
|
switch "$1"
|
|
case _
|
|
set items $items $2
|
|
|
|
case index
|
|
set option index
|
|
|
|
case path
|
|
set option path
|
|
set path $2
|
|
|
|
case m me self fisher{,man}
|
|
set option $option me
|
|
|
|
case q quiet
|
|
if test -z "$2"
|
|
set 2 /dev/null
|
|
end
|
|
|
|
set error $2
|
|
|
|
case help h
|
|
printf "usage: fisher update [<name or url> ...] [--me] [--quiet] [--help]\n\n"
|
|
|
|
printf " -m --me Update Fisherman\n"
|
|
printf " -q --quiet Enable quiet mode\n"
|
|
printf " -h --help Show usage help \n"
|
|
return
|
|
|
|
case \*
|
|
printf "fisher: '%s' is not a valid option\n" $1 >& 2
|
|
fisher_update --help >& 2
|
|
return 1
|
|
end
|
|
end
|
|
|
|
switch "$option"
|
|
case path
|
|
if not test -d $path
|
|
printf "fisher: '%s' invalid path\n" $path > $error
|
|
return 1
|
|
end
|
|
|
|
wait --spin=pipe --log=$fisher_error_log "
|
|
git -C $path checkout --quiet master ^/dev/null
|
|
git -C $path pull --quiet --rebase origin master"
|
|
|
|
case index
|
|
mkdir -p $fisher_cache
|
|
set -l index $fisher_cache/.index.tmp
|
|
|
|
if curl -s $fisher_index > $index
|
|
mv -f $index $fisher_cache/.index
|
|
end
|
|
|
|
rm -f $index
|
|
|
|
case me
|
|
set -l elap (date +%s)
|
|
|
|
printf "Updating >> Fisherman\n" > $error
|
|
|
|
if not fisher_update --path=$fisher_home --quiet=$error
|
|
return 1
|
|
end
|
|
|
|
printf "Done without errors (%0.fs)\n" (math (date +%s) - $elap) > $error
|
|
|
|
case \*
|
|
set -l elap (date +%s)
|
|
set -l count 0
|
|
set -l total (count $items)
|
|
|
|
if set -q items[1]
|
|
printf "%s\n" $items
|
|
else
|
|
fisher --file=-
|
|
end | fisher --validate | fisher --translate | while read -l path
|
|
|
|
if not test -d "$path"
|
|
printf "fisher: '%s' not found\n" $path > $error
|
|
continue
|
|
end
|
|
|
|
set -l name (basename $path)
|
|
|
|
printf "Updating " > $error
|
|
|
|
switch $total
|
|
case 0 1
|
|
printf ">> %s\n" $name > $error
|
|
|
|
case \*
|
|
printf "(%s of %s) >> %s\n" (math 1 + $count) $total $name > $error
|
|
end
|
|
|
|
if not fisher_update --path=$path --quiet=$error
|
|
sed -nE 's/.*(error|fatal): (.*)/error: \2/p' $fisher_error_log > $error
|
|
continue
|
|
end
|
|
|
|
fisher install $name --quiet
|
|
|
|
set count (math $count + 1)
|
|
end
|
|
|
|
printf "%d plugin/s updated (%0.fs)\n" $count (math (date +%s) - $elap) > $error
|
|
|
|
test $count -gt 0
|
|
end
|
|
end
|