mirror of
https://github.com/jorgebucaran/fisher
synced 2024-07-02 23:11:48 +02:00
ebec1eaa01
* Deprecate fisher --list in favor of a new command fisher list. The behavior is roughly the same. See fisher help list for usage. tl;dr: Use list to query the local system / cache and search to query the index. * Teach fisher_plugin_walk about fish_postexec, fish_command_not_found and fish_preexec event emitters and erase them during uninstall if they were defined in a snippet. * Fisherman now recognizes the following aliases by default: i for install, u for update, l for list, s for search and h for help. * Large documentation rewrite. Better, simpler, more concise and more consistent. * Fisherman now detects if users have modified their fish prompt using fish_config and if so, uninstalls $fisher_prompt.
124 lines
3.3 KiB
Fish
124 lines
3.3 KiB
Fish
function fisher_uninstall -d "Uninstall plugins"
|
|
set -l plugins
|
|
set -l option
|
|
set -l stdout /dev/stdout
|
|
set -l stderr /dev/stderr
|
|
|
|
getopts $argv | while read -l 1 2
|
|
switch "$1"
|
|
case _
|
|
set plugins $plugins $2
|
|
|
|
case f force
|
|
set option force
|
|
|
|
case q quiet
|
|
set stdout /dev/null
|
|
set stderr /dev/null
|
|
|
|
case h
|
|
printf "Usage: fisher uninstall [<plugins>] [--force] [--quiet] [--help]\n\n"
|
|
printf " -f --force Delete copy from the cache\n"
|
|
printf " -q --quiet Enable quiet mode\n"
|
|
printf " -h --help Show usage help\n"
|
|
return
|
|
|
|
case \*
|
|
printf "fisher: '%s' is not a valid option.\n" $1 > /dev/stderr
|
|
fisher_uninstall -h > /dev/stderr
|
|
return 1
|
|
end
|
|
end
|
|
|
|
set -l time (date +%s)
|
|
set -l count 0
|
|
set -l index 1
|
|
set -l total (count $plugins)
|
|
set -l skipped
|
|
|
|
set -l IFS \t
|
|
|
|
if set -q plugins[1]
|
|
printf "%s\n" $plugins
|
|
else
|
|
__fisher_file
|
|
|
|
end | while read -l item path
|
|
debug "Validate %s" $item
|
|
debug "Shit %s" $path
|
|
|
|
if not set item (__fisher_plugin_validate $item)
|
|
debug "Validate fail %s" $item
|
|
printf "fisher: '%s' is not a valid name, path or URL.\n" $item > $stderr
|
|
continue
|
|
end
|
|
|
|
debug "Validate pass %s" $item
|
|
|
|
if not set path (__fisher_path_from_plugin $item)
|
|
set total (math $total - 1)
|
|
printf "fisher: '%s' not found\n" $item > $stderr
|
|
continue
|
|
end
|
|
|
|
set -l name (printf "%s\n" $path | __fisher_name)
|
|
|
|
debug "Uninstall %s" "$name"
|
|
|
|
if not contains -- $name (fisher_list $fisher_file)
|
|
if test -z "$option"
|
|
set total (math $total - 1)
|
|
set skipped $skipped $name
|
|
continue
|
|
end
|
|
end
|
|
|
|
printf "Uninstalling " > $stderr
|
|
|
|
switch $total
|
|
case 0 1
|
|
printf ">> %s\n" $name > $stderr
|
|
|
|
case \*
|
|
printf "(%s of %s) >> %s\n" $index $total $name > $stderr
|
|
set index (math $index + 1)
|
|
end
|
|
|
|
if __fisher_plugin_can_enable "$name" "$path"
|
|
debug "Plugin disable %s w/ option %s" "$name" "$option"
|
|
__fisher_plugin_disable "$name" "$path" "$option"
|
|
else
|
|
debug "Plugin can't dissable %s" "$name"
|
|
end
|
|
|
|
if test "$option" = force
|
|
debug "Remove path '%s'" "$path"
|
|
command rm -rf $path
|
|
end
|
|
|
|
set count (math $count + 1)
|
|
end
|
|
|
|
set time (math (date +%s) - $time)
|
|
|
|
if test ! -z "$skipped"
|
|
printf "%s plugin/s skipped (%s)\n" (count $skipped) (
|
|
printf "%s\n" $skipped | paste -sd ' ' -
|
|
) > $stdout
|
|
end
|
|
|
|
if test $count -le 0
|
|
printf "No plugins were uninstalled.\n" > $stdout
|
|
return 1
|
|
end
|
|
|
|
debug "Reset completions and key bindings start"
|
|
|
|
__fisher_complete_reset
|
|
__fisher_key_bindings_reset
|
|
|
|
debug "Reset completions and key bindings done"
|
|
|
|
printf "Aye! %d plugin/s uninstalled in %0.fs\n" $count $time > $stdout
|
|
end
|