mirror of
https://github.com/jorgebucaran/fisher
synced 2024-07-06 23:11:48 +02:00
a25fc7353e
Remove scripts directory in favor of using the functions/ or root for sharing scripts. Using a scripts directory does not solve the main problem of sharing scripts with the same name, so this addition was deemed of little value. In the future, a more robust way to avoid name collisions when sharing scripts would be nice to have, but at the moment having a scripts directory is not solving this problem but just adding clutter to the configuration. Closes #105.
42 lines
1.3 KiB
Fish
42 lines
1.3 KiB
Fish
function __fisher_plugin_walk -a plugin path
|
|
for file in $path/{*,{conf.d,modules}/*,functions/**}.{fish,load} $path/completions/*.fish
|
|
set -l name (basename $file .fish)
|
|
set -l base $name.fish
|
|
|
|
switch $file
|
|
case \*/{fish_user_,}key_bindings.fish
|
|
printf "%s %s %s\n" --bind $file
|
|
|
|
case \*/uninstall.fish
|
|
printf "%s %s\n" --uninstall $file
|
|
|
|
case \*/completions/\*.fish
|
|
printf "%s %s %s\n" --source $file completions/$base
|
|
|
|
case \*/{conf.d,modules}/\?\* \*/\*config.fish \*/{before.,}init.fish \*/$plugin.load
|
|
switch "$base"
|
|
case \*$plugin\*
|
|
case \*
|
|
set base $plugin.$base
|
|
end
|
|
|
|
printf "%s %s %s\n" --source $file conf.d/$base
|
|
|
|
case \*
|
|
printf "%s %s %s %s\n" --source $file functions/$base $name
|
|
end
|
|
end
|
|
|
|
for file in $path/{functions/,}*.{py,rb,php,pl,awk,sed}
|
|
set -l base (basename $file)
|
|
|
|
printf "%s %s %s\n" -- $file functions/$base
|
|
end
|
|
|
|
for n in (seq 9)
|
|
for file in $path/man/man$n/*.$n
|
|
printf "%s %s %s\n" --man $file man/man$n/(basename $file)
|
|
end
|
|
end
|
|
end
|